/* Some common screw dimensions and helper functions/modules */

inf = 400;

/********************************************************************************/
// M3 dimensions
m3HoleRadiusSlack = 0.15;
m3Diameter = 3.0;
m3Radius = m3Diameter / 2.0;
m3RadiusSlacked = m3Radius + m3HoleRadiusSlack;
m3HexNutWidthAcrossFlats = 5.41;
m3HexNutWidthAcrossCorners = FtoG(m3HexNutWidthAcrossFlats);
m3HexNutThickness = 2.18;

/********************************************************************************/
// M4 dimensions
m4HoleRadiusSlack = 0.15;
m4Diameter = 4.0;
m4Radius = m4Diameter / 2.0;
m4RadiusSlacked = m4Radius + m4HoleRadiusSlack;
m4HexNutWidthAcrossFlats = 6.89;
m4HexNutWidthAcrossCorners = FtoG(m4HexNutWidthAcrossFlats);
m4HexNutThickness = 3.07;

/********************************************************************************/
function screwRadiusSlacked(screwType) =
  (screwType == "m3")
  ? m3RadiusSlacked
  : (screwType == "m4")
  ? m4RadiusSlacked
  : error("Unsupported screw type");


module hexNutPocket_N(screwType) {
  if (screwType == "m3") {
    hexNutPocketHelper_N(m3RadiusSlacked,
        m3HexNutWidthAcrossCorners / 2 + 0.1,
      m3HexNutThickness + 0.2);
  } else if (screwType == "m4") {
    hexNutPocketHelper_N(m4RadiusSlacked,
        m4HexNutWidthAcrossCorners / 2 + 0.1,
      m4HexNutThickness + 0.2);
  } else {
    error("Unsupported screw type");
  }
}

module hexNutPocketHelper_N(
innerRadius,
widthAcrossCorners,
thickness)
{
  union() {

    hull() {
      // hexagonal cylinder representing where the nut should fit
      cylinder(r = widthAcrossCorners, h = thickness, center = true, $fn = 6);

      // negative volume for sliding in the nut
      translate(v = [inf, 0, 0])
      cylinder(r = widthAcrossCorners, h = thickness, center = true, $fn = 6);
    }

    // negative volume for screw lead
    translate(v = [0, 0, - 10])
    cylinder(r = innerRadius, h = inf, $fn = 32);

    hull() {
      translate(v = [inf, 0, 0])
      cylinder(r = innerRadius, h = inf, $fn = 32);
      cylinder(r = innerRadius, h = inf, $fn = 32);
    }
  }
}

// Convert a regular hexagon widthAcrossFlats to widthAcrossCorners
function FtoG(widthAcrossFlats) = widthAcrossFlats * (2 / sqrt(3));

// Convert a regular hexagon widthAcrossCorners to widthAcrossFlats
function GtoF(widthAcrossCorners) = widthAcrossCorners * (sqrt(3) / 2);