refactor

rack2/config.scad

@@ -0,0 +1,34 @@
+/*
+   case-files v2
+   This file contains parameters used for declaring/generating a customized rack frame.
+
+   - All dimensions are in millimetres (mm) unless stated otherwise.
+   - A "_N" appended to a module is meant to denote that this module is a negative volume, and should only be used to
+     substract from other volumes.
+*/
+
+// Maximum width for rackmount units. Change this according your max expected enclosure width.
+// Changing this will directly affect the required build volume.
+maxUnitWidth = 200;
+
+// Maximum (recommended) unit depth. There technically isn't a max unit depth because there's no physical bound on
+// how far a rack unit can extrude back. This parameter basically controls the distance between the front of the front
+// rails and the back of the back rails. Changing this will directly affect the required build volume.
+maxUnitDepth = 200;
+
+// Vertical distance between the midpoint of adjacent screws mounts. Affects build volume.
+screwDiff = 10;
+
+// Number screw slots on the main rail. Affects build volume.
+numRailScrews = 20;
+
+// Screw type used for rackmount units. See screws.scad.
+mainRailScrewType = "m4";
+
+// Screw type used to affix side rails.
+mainRailSideMountScrewType = "m4";
+
+// Screw type used for constructing the actual rack frame.
+rackFrameScrewType = "m3";
+// Currently, only m3 screws are supported here (tolerance issues)
+assert(rackFrameScrewType == "m3");

rack2/connectingBar.scad

@@ -0,0 +1,85 @@
+include <../math.scad>
+include <./config.scad>
+include <./screws.scad>
+include <./mainRail.scad>
+include <./helper/sphericalFilet.scad>
+include <./helper/cylindricalFilet.scad>
+
+
+// TODO: How do I nicely explain this?
+railSlotSpacing = 4;
+sideSpacing = 12;
+
+barDepth = maxUnitDepth + 2*railSlotSpacing;
+barWidth = railSlotSpacing + railTotalWidth + sideSpacing;
+barHeight = 15;
+
+barWallThickness = 3;
+barRoundness = 12;
+
+echo("Bar total depth: ", barDepth);
+echo("Bar total width: ", barWidth);
+
+module connectingBar() {
+
+  module _positive() {
+    minkowski() {
+      difference() {
+        sphericalFiletEdge(barWidth, barDepth, barHeight, barRoundness);
+
+        translate(v = [barWallThickness, 40, barWallThickness])
+        cylindricalFiletEdge(barWidth, barDepth-80, barHeight, barRoundness);
+      }
+    }
+  }
+
+
+  module _stackConn() {
+    translate(v=[0,0,0])
+    cube(size = [10, 10, 5]);
+
+    translate(v=[5,5,5])
+    cylinder(r=2, h=2);
+  }
+
+  module _sideConnector() {
+    //translate(v=[1.5, railTotalDepth - 4, -m3HeatSetInsertSlotHeightSlacked])
+    rotate(a=[0,90,0])
+    heatSetInsertSlot_N(rackFrameScrewType);
+  }
+
+  module _test() {
+    difference() {
+      _positive();
+
+      union() {
+        translate(v=[10,10,0])
+        _stackConn();
+
+        translate(v=[barWidth - (railTotalWidth + railSlotSpacing), railSlotSpacing, barHeight - railFootThickness])
+        railFeetSlot_N();
+
+        translate(v=[barWidth - m3HeatSetInsertSlotHeightSlacked + eps, 6, 7.5])
+        _sideConnector();
+
+        translate(v=[barWidth - m3HeatSetInsertSlotHeightSlacked + eps, 35, 7.5])
+        _sideConnector();
+      }
+    }
+
+  }
+  _test();
+
+  translate(v=[barWidth - m3HeatSetInsertSlotHeightSlacked + eps, 6, 7.5])
+  _sideConnector();
+
+}
+
+connectingBar();
+
+
+intersection() {
+  connectingBar();
+
+  cube(size=[15,100,100]);
+}

rack2/helper/cylindricalFilet.scad

@@ -0,0 +1,16 @@
+
+module cylindricalFiletEdge(width, depth, height, roundness) {
+  rd = roundness;
+
+  intersection() {
+    minkowski() {
+      rotate(a = [90, 0, 0])
+      cylinder(r = rd, h = eps);
+
+      translate(v = [rd, 0, rd])
+      cube(size = [width, depth, height]);
+    }
+
+    cube(size = [width, depth, height]);
+  }
+}

rack2/helper/sphericalFilet.scad

@@ -0,0 +1,15 @@
+
+module sphericalFiletEdge(width, depth, height, roundness) {
+  rd = roundness;
+
+  intersection() {
+    minkowski() {
+      sphere(r = rd);
+
+      translate(v = [rd, rd, rd])
+      cube(size = [width*2, depth - 2*rd, height*2]);
+    }
+
+    cube(size = [width, depth, height]);
+  }
+}

rack2/mainRail.scad

@@ -0,0 +1,131 @@
+include <./config.scad>
+include <../math.scad>
+include <./screws.scad>
+
+/* Small horizontal planes at the top and bottom of the main rails. Used so we can fasten the rail to the frame
+   Note that this value is also used for a depression at the bottom/top of the frame for aligning the rail */
+railFootThickness = 3;
+
+railTotalHeight = screwDiff * (numRailScrews + 1) + 2 * railFootThickness;
+
+// Distance between the middle of a screw mount and the rail's vertical edges
+railScrewHoleToInnerEdge = 5;
+railScrewHoleToOuterEdge = 5;
+
+// Distance between the midpoint of the rail screw holes.
+rackMountScrewWidth = maxUnitWidth + 2 * railScrewHoleToInnerEdge;
+
+railFrontThickness = 6; // Make sure that the nuts for the chosen screw type can slot within the front face
+railSideMountThickness = 2.5;
+railOtherThickness = 2.5;
+
+// Extra spacing for screws.
+frontScrewSpacing = 8;
+
+sideSupportExtraSpace = 2;
+sideSupportScrewHoleToFrontEdge = 5;
+sideSupportScrewHoleToBackEdge = 4.5;
+sideSupportDepth = sideSupportScrewHoleToBackEdge + sideSupportScrewHoleToFrontEdge;
+
+frontFaceWidth = railScrewHoleToInnerEdge + railScrewHoleToOuterEdge;
+
+railTotalWidth = frontFaceWidth;
+railTotalDepth = railFrontThickness+railOtherThickness+frontScrewSpacing+sideSupportDepth;
+
+
+*mainRail();
+echo("Total Rail Height: ", railTotalHeight);
+
+module mainRail() {
+
+  union() {
+    _frontRailSegment();
+
+    translate(v = [0, railFrontThickness, 0])
+    _connectingLBracketRailSegment();
+
+    translate(v = [frontFaceWidth-sideSupportExtraSpace, railFrontThickness+railOtherThickness+frontScrewSpacing, 0])
+    rotate(a = [0, 0, 90])
+    _sideSupportSegment();
+
+
+    translate(v = [0, railFrontThickness + railOtherThickness + frontScrewSpacing, 0]) {
+
+      _railFeet();
+
+      translate(v = [0, 0, railTotalHeight - railFootThickness])
+      _railFeet();
+    }
+  }
+
+  module _frontRailSegment() {
+    difference() {
+      cube(size = [frontFaceWidth, railFrontThickness, railTotalHeight]);
+
+      for (i = [1:numRailScrews]) {
+        translate(v = [railScrewHoleToOuterEdge, railFrontThickness / 2, i * screwDiff + railFootThickness])
+        rotate(a = [90, 0, 0])
+        hexNutPocket_N(mainRailScrewType);
+      }
+    }
+  }
+
+  module _connectingLBracketRailSegment() {
+    difference() {
+      cube(size = [railOtherThickness, frontScrewSpacing + railOtherThickness, railTotalHeight]);
+
+      union() {
+        translate(v = [0, 4, railFootThickness + screwDiff / 2])
+        rotate(a = [0, 90, 0])
+        cylinder(r = screwRadiusSlacked(rackFrameScrewType), h = 10, $fn = 32, center = true);
+
+        translate(v = [0, 4, railTotalHeight - (railFootThickness + screwDiff / 2)])
+        rotate(a = [0, 90, 0])
+        cylinder(r = screwRadiusSlacked(rackFrameScrewType), h = inf10, $fn = 32, center = true);
+      }
+    }
+
+    translate(v = [0, frontScrewSpacing + railOtherThickness, 0])
+    rotate(a = [0, 0, 270])
+    cube(size = [railOtherThickness, frontFaceWidth - sideSupportExtraSpace, railTotalHeight]);
+  }
+
+
+  module _sideSupportSegment() {
+    difference() {
+      cube(size = [sideSupportDepth, railSideMountThickness, railTotalHeight]);
+
+      for (i = [1:numRailScrews]) {
+        translate(v = [sideSupportScrewHoleToFrontEdge, railFrontThickness / 2, i * screwDiff + railFootThickness])
+        rotate(a = [90, 0, 0])
+        cylinder(r = screwRadiusSlacked(mainRailSideMountScrewType), h = inf10, $fn = 32);
+      }
+    }
+
+  }
+
+  module _railFeet() {
+    difference() {
+      cube(size = [frontFaceWidth - sideSupportExtraSpace, sideSupportDepth, railFootThickness]);
+
+      hull() {
+        translate(v = [1.5, 5, 0])
+        cylinder(r = screwRadiusSlacked(rackFrameScrewType), h = inf10, $fn = 32);
+
+        translate(v = [0, 5, 0])
+        cube(size = [eps, screwRadiusSlacked(rackFrameScrewType) * 2, 10], center = true);
+      }
+    }
+  }
+
+}
+
+module railFeetSlot_N() {
+
+  union() {
+    cube(size = [railTotalWidth, railTotalDepth, railFootThickness]);
+
+    translate(v=[1.5, railTotalDepth - 4, -m3HeatSetInsertSlotHeightSlacked])
+    heatSetInsertSlot_N(rackFrameScrewType);
+  }
+}

rack2/screws.scad

@@ -0,0 +1,97 @@
+/* Some common screw dimensions and helper functions/modules */
+
+include <../math.scad>
+include <../common.scad>
+
+/********************************************************************************/
+// M3 dimensions
+m3HoleRadiusSlack = 0.15;
+m3Diameter = 3.0;
+m3Radius = m3Diameter / 2.0;
+m3RadiusSlacked = m3Radius + m3HoleRadiusSlack;
+
+m3HexNutWidthAcrossFlats = 5.41;
+m3HexNutWidthAcrossCorners = FtoG(m3HexNutWidthAcrossFlats);
+m3HexNutThickness = 2.18;
+
+m3HeatSetInsertSlotRadiusSlack = 0.0;
+m3HeatSetInsertSlotHeightSlack = 0.5;
+
+m3HeatSetInsertSlotRadius = 2.5;
+m3HeatSetInsertSlotHeight = 6;
+
+m3HeatSetInsertSlotRadiusSlacked = m3HeatSetInsertSlotRadius+m3HeatSetInsertSlotRadiusSlack;
+m3HeatSetInsertSlotHeightSlacked = m3HeatSetInsertSlotHeight+m3HeatSetInsertSlotHeightSlack;
+
+/********************************************************************************/
+// M4 dimensions
+m4HoleRadiusSlack = 0.15;
+m4Diameter = 4.0;
+m4Radius = m4Diameter / 2.0;
+m4RadiusSlacked = m4Radius + m4HoleRadiusSlack;
+m4HexNutWidthAcrossFlats = 6.89;
+m4HexNutWidthAcrossCorners = FtoG(m4HexNutWidthAcrossFlats);
+m4HexNutThickness = 3.07;
+
+/********************************************************************************/
+
+module heatSetInsertSlot_N(screwType) {
+  if (screwType == "m3") {
+    union() {
+      // actual slot for insert
+      cylinder(h = m3HeatSetInsertSlotHeightSlacked, r = m3HeatSetInsertSlotRadiusSlacked);
+
+      // extra space above slot to help with insertion
+      translate(v=[0, 0, m3HeatSetInsertSlotHeightSlacked])
+      cylinder(h = inf50, r = 1.3*m3HeatSetInsertSlotRadiusSlacked);
+    }
+  } else {
+    error("Unsupported screw type");
+  }
+}
+
+function screwRadiusSlacked(screwType) =
+  (screwType == "m3")
+  ? m3RadiusSlacked
+  : (screwType == "m4")
+  ? m4RadiusSlacked
+  : error("Unsupported screw type");
+
+module hexNutPocket_N(screwType) {
+  if (screwType == "m3") {
+    hexNutPocketHelper_N(m3RadiusSlacked, m3HexNutWidthAcrossCorners / 2 + 0.1, m3HexNutThickness + 0.2);
+  } else if (screwType == "m4") {
+    hexNutPocketHelper_N(m4RadiusSlacked, m4HexNutWidthAcrossCorners / 2 + 0.1, m4HexNutThickness + 0.2);
+  } else {
+    error("Unsupported screw type");
+  }
+}
+
+module hexNutPocketHelper_N(innerRadius, widthAcrossCorners, thickness) {
+  union() {
+    hull() {
+      // hexagonal cylinder representing where the nut should fit
+      cylinder(r = widthAcrossCorners, h = thickness, center = true, $fn = 6);
+
+      // negative volume for sliding in the nut
+      translate(v = [inf50, 0, 0])
+      cylinder(r = widthAcrossCorners, h = thickness, center = true, $fn = 6);
+    }
+
+    // negative volume for screw lead
+    translate(v = [0, 0, - 10])
+    cylinder(r = innerRadius, h = inf50, $fn = 32);
+
+    hull() {
+      translate(v = [inf50, 0, 0])
+      cylinder(r = innerRadius, h = inf50, $fn = 32);
+      cylinder(r = innerRadius, h = inf50, $fn = 32);
+    }
+  }
+}
+
+// Convert a regular hexagon widthAcrossFlats to widthAcrossCorners
+function FtoG(widthAcrossFlats) = widthAcrossFlats * (2 / sqrt(3));
+
+// Convert a regular hexagon widthAcrossCorners to widthAcrossFlats
+function GtoF(widthAcrossCorners) = widthAcrossCorners * (sqrt(3) / 2);